Windows AI開発環境構築ガイド

開発環境とビルドツールの準備

目標

本章の目標は、自身のパソコンでAIプログラミングの実行と実験が可能な環境を構築することである。本章を完了すると、さまざまなAIプログラムを動作させ、ソースコードの確認や修正ができる環境が整う。

1.1 概要

Windows環境でAIプログラミングを始めるための開発環境を構築する。Python、GPU計算基盤、AIエディタを導入することで、機械学習モデルの実行や実験、AIによるコード生成支援を活用した開発が可能になる。各ソフトウェアはコマンドラインから一括でインストールでき、パスの設定も自動化されるため、環境構築の手間を軽減できる。

本ガイドでは以下のソフトウェアをインストールする。

開発環境とビルドツール

1.2 実行前の確認事項

• ディスク空き容量が20GB以上あることを確認する
• すでにPythonがインストール済みの場合は、基本的にそのまま使用する

1.3 ソフトウェアのインストール（Windows）

Windowsでは、wingetというWindowsの公式パッケージ管理ツールを用いて多くのソフトウェアをインストールできる。管理者権限で実行し、システム全体にインストールすることを推奨する。

なお，下にあるコマンドの詳細説明と，ここでインストールされるAIエディタの概要説明は，別ページ（Windows Python 開発環境とビルドツール構築ガイド ）にあるので，必要に応じてアクセスしてほしい．

管理者権限でコマンドプロンプトを起動（手順：Windowsキーまたはスタートメニュー → cmdと入力 → 右クリック → 「管理者として実行」）し、以下を実行する。wingetの--scope machineオプションでシステム全体にインストールするには、管理者権限が必要である。

REM 開発環境セットアップスクリプト（管理者権限で実行）

REM 管理者権限チェック
net session >nul 2>&1
if errorlevel 1 (
    echo 管理者権限で実行してください
    exit /b 1
)

REM Python 3.12 をシステム領域にインストール
winget install --scope machine --id Python.Python.3.12 -e --silent --accept-source-agreements --accept-package-agreements

REM パス長制限の解除
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\FileSystem" /v LongPathsEnabled /t REG_DWORD /d 1 /f
reg query "HKLM\SYSTEM\CurrentControlSet\Control\FileSystem" /v LongPathsEnabled

REM Python のパス設定
set "PYTHON_PATH=C:\Program Files\Python312"
set "PYTHON_SCRIPTS_PATH=C:\Program Files\Python312\Scripts"
if exist "%PYTHON_PATH%" setx PYTHON_PATH "%PYTHON_PATH%" /M >nul
if exist "%PYTHON_SCRIPTS_PATH%" setx PYTHON_SCRIPTS_PATH "%PYTHON_SCRIPTS_PATH%" /M >nul
for /f "skip=2 tokens=2*" %a in ('reg query "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v Path') do set "SYSTEM_PATH=%b"
echo "%SYSTEM_PATH%" | find /i "%PYTHON_PATH%" >nul
if errorlevel 1 setx PATH "%PYTHON_PATH%;%PYTHON_SCRIPTS_PATH%;%SYSTEM_PATH%" /M >nul

REM Visual Studio 2022 Build Toolsとランタイムをシステム領域にインストール
winget install --scope machine --wait --accept-source-agreements --accept-package-agreements Microsoft.VisualStudio.2022.BuildTools Microsoft.VCRedist.2015+.x64

REM インストーラーとインストールパスの設定
set "VS_INSTALLER=C:\Program Files (x86)\Microsoft Visual Studio\Installer\vs_installer.exe"
set "VS_PATH=C:\Program Files\Microsoft Visual Studio\2022\BuildTools"

REM C++開発ワークロードのインストール
"%VS_INSTALLER%" modify --installPath "%VS_PATH%" --add Microsoft.VisualStudio.Workload.VCTools --includeRecommended --quiet --norestart
"%VS_INSTALLER%" modify --installPath "%VS_PATH%" --add Microsoft.VisualStudio.Component.VC.Tools.x86.x64 --includeRecommended --quiet --norestart
"%VS_INSTALLER%" modify --installPath "%VS_PATH%" --add Microsoft.VisualStudio.Component.Windows11SDK.22621 --includeRecommended --quiet --norestart

REM Rust をシステム全体にインストール
curl -o rustup-init.exe https://static.rust-lang.org/rustup/dist/x86_64-pc-windows-msvc/rustup-init.exe
set "RUSTUP_HOME=C:\Rust\rustup"
set "CARGO_HOME=C:\Rust\cargo"
setx RUSTUP_HOME "%RUSTUP_HOME%" /M
setx CARGO_HOME "%CARGO_HOME%" /M
rustup-init.exe -y
for /f "skip=2 tokens=2*" %a in ('reg query "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v Path') do set "SYSTEM_PATH=%b"
setx PATH "%CARGO_HOME%\bin;%SYSTEM_PATH%" /M
del rustup-init.exe

REM Git をシステム領域にインストール
winget install --scope machine --id Git.Git -e --silent --accept-source-agreements --accept-package-agreements

REM Git のパス設定
set "GIT_PATH=C:\Program Files\Git\cmd"
for /f "skip=2 tokens=2*" %a in ('reg query "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v Path') do set "SYSTEM_PATH=%b"
if exist "%GIT_PATH%" (
    echo "%SYSTEM_PATH%" | find /i "%GIT_PATH%" >nul
    if errorlevel 1 setx PATH "%GIT_PATH%;%SYSTEM_PATH%" /M >nul
)

REM CMakeをシステム領域にインストール
winget install --scope machine --id Kitware.CMake -e --silent

REM CMakeのパス設定
set "CMAKE_PATH=C:\Program Files\CMake\bin"
for /f "skip=2 tokens=2*" %a in ('reg query "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v Path') do set "SYSTEM_PATH=%b"
if exist "%CMAKE_PATH%" (
    echo "%SYSTEM_PATH%" | find /i "%CMAKE_PATH%" >nul
    if errorlevel 1 setx PATH "%CMAKE_PATH%;%SYSTEM_PATH%" /M >nul
)

REM 7-Zip をシステム領域にインストール
winget install --scope machine --id 7zip.7zip -e --silent --accept-source-agreements --accept-package-agreements

REM 7-Zip のパス設定
set "SEVENZIP_PATH=C:\Program Files\7-Zip"
for /f "skip=2 tokens=2*" %a in ('reg query "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v Path') do set "SYSTEM_PATH=%b"
if exist "%SEVENZIP_PATH%" (
    echo "%SYSTEM_PATH%" | find /i "%SEVENZIP_PATH%" >nul
    if errorlevel 1 setx PATH "%SEVENZIP_PATH%;%SYSTEM_PATH%" /M >nul
)

REM CUDAをシステム領域にインストール
winget install --scope machine --id Nvidia.CUDA --version 12.6 -e --silent --accept-package-agreements --accept-source-agreements
winget install --scope machine --id Microsoft.VCRedist.2015+.x64 -e --silent --accept-package-agreements --accept-source-agreements

REM CUDA のパス設定
set "CUDA_PATH=C:\Program Files\NVIDIA GPU Computing Toolkit\CUDA\v12.6"
set "CUDNN_PATH=C:\Program Files\NVIDIA GPU Computing Toolkit\CUDA\v12.6"
if exist "%CUDA_PATH%" setx CUDA_PATH "%CUDA_PATH%" /M >nul
if exist "%CUDNN_PATH%" setx CUDNN_PATH "%CUDNN_PATH%" /M >nul
for /f "skip=2 tokens=2*" %a in ('reg query "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v Path') do set "SYSTEM_PATH=%b"
if exist "%CUDA_PATH%\bin" (
    echo "%SYSTEM_PATH%" | find /i "%CUDA_PATH%\bin" >nul
    if errorlevel 1 setx PATH "%CUDA_PATH%\bin;%SYSTEM_PATH%" /M >nul
)

REM 環境変数TEMP, TMPの設定
mkdir C:\TEMP
set "TEMP_PATH=C:\TEMP"
setx TEMP "%TEMP_PATH%" /M >nul
setx TMP "%TEMP_PATH%" /M >nul

REM PyTorch をインストール
set "PYTHON_PATH=C:\Program Files\Python312"
"%PYTHON_PATH%\Scripts\pip" install -U torch torchvision torchaudio --index-url https://download.pytorch.org/whl/cu126

REM JupyterLab をインストール
set "PYTHON_PATH=C:\Program Files\Python312"
"%PYTHON_PATH%\Scripts\pip" install -U jupyterlab

REM Windsurf をシステム領域にインストール
winget install --scope machine --id Codeium.Windsurf -e --silent --accept-source-agreements --accept-package-agreements
if exist "C:\Program Files\Windsurf\bin" "C:\Program Files\Windsurf\bin\windsurf" --install-extension MS-CEINTL.vscode-language-pack-ja

REM Microsoft VS Code をシステム領域にインストール
winget install --scope machine --id Microsoft.VisualStudioCode -e --silent --accept-source-agreements --accept-package-agreements

REM VS Code 拡張機能のインストール（Python環境、日本語化、Cline、GitHub Copilot）
if exist "C:\Program Files\Microsoft VS Code\bin" cd "C:\Program Files\Microsoft VS Code\bin"
if exist "C:\Program Files\Microsoft VS Code\bin" code --install-extension ms-python.python
if exist "C:\Program Files\Microsoft VS Code\bin" code --install-extension ms-python.vscode-pylance
if exist "C:\Program Files\Microsoft VS Code\bin" code --install-extension MS-CEINTL.vscode-language-pack-ja
if exist "C:\Program Files\Microsoft VS Code\bin" code --install-extension dongli.python-preview
if exist "C:\Program Files\Microsoft VS Code\bin" code --install-extension saoudrizwan.claude-dev
if exist "C:\Program Files\Microsoft VS Code\bin" code --install-extension GitHub.copilot

echo セットアップ完了

実行時のヒント

• コマンドの途中で止まった場合は、まずEnterキーを1回押す。それでも進まない場合は、エラー内容をよく読む
• Pythonのインストール時に「Modify Repair Uninstall」画面が出た場合は、Pythonがインストール済みであるため「Cancel」をクリックする

1.4 確認

次のプログラムを実行し、Pythonのバージョン、Gitのバージョン、PyTorchのバージョン、GPUの動作を確認する。Python 3.12、NVIDIA CUDA、Git、PyTorchのインストールに問題がないかも確認できる。

import sys
import subprocess
import torch

print(sys.version)
print(subprocess.check_output(['git', '--version'], text=True).strip())
print(torch.__version__)
print(torch.cuda.is_available())

第2章 はじめに：AI開発環境の全体像

このガイドは、Windows PC上でAI開発を始めたいと考えている学生や技術者を対象としている。本ガイドでは、AI開発で広く使われるプログラミング言語Python、基本的なデータ処理ライブラリ、そして開発を助けるコードエディタを中心に、シンプルかつ実践的なAI開発環境を構築することを目指す。このガイドの手順に沿って環境を構築すれば、簡単なデータ分析、機械学習モデルの実行、ディープラーニングの入門的なコードの実験ができるようになる。

対象とするPC環境はWindows 11である。NVIDIA製GPUがある場合はGPUを活用した開発環境も構築できるが、GPUがない場合でもCPUのみで多くの学習・開発を行うことは可能である。深層学習ではGPUを使用することで計算速度が向上する。

インストールの実行には、PCのディスク空き容量が20GB以上必要である。事前に確認し、空き容量が無い場合は実施しないこと。

このガイドが、Windows AI開発環境構築とその後の学習・開発活動に役立つことを期待する。

第3章 ガイドが対象とするAI開発環境

本ガイドでは、AI開発環境として、以下のツール群の役割、メリット、そしてインストール手順を解説する。10章では、環境構築後の学習の方向性を案内している。

• プログラミング言語: Python（AIやデータサイエンスで広く使われている）
• バージョン管理: Git（プログラムコードの変更履歴を記録・管理し、GitHubとの同期にも使用）
• GPU利用基盤: NVIDIA CUDA（NVIDIA GPU上で並列計算を実行するためのプラットフォーム）
• Pythonライブラリ: PyTorch, NumPy, Pandas, Scikit-learn, Matplotlib, Seabornなど
• 開発エディタ: Visual Studio Code（多機能なコードエディタ）, Jupyter Notebook, Windsurf（AI支援機能を特徴とする開発環境）
• ユーティリティ: 7-Zip（ファイルの圧縮・展開を行うツール）

+-----------------------------------------------------------------+
| 開発エディタ (VS Code / Jupyter Notebook / Windsurf)            |
|  +------------------------------------------------------------+ |
|  | Git (バージョン管理)                                       | |
|  +------------------------------------------------------------+ |
|                                                                |
|  +------------------------------------------------------------+ |
|  | Python + AIコアライブラリ (PyTorch, NumPy, Pandasなど)     | |
|  +------------------------------------------------------------+ |
|                                                                |
+-----------------------------------------------------------------+
| 基盤 (OSとハードウェアの橋渡し)                                 |
|  +---------------------------+  <--連携-->  +-----------------+ |
|  | PyTorch内のCUDAライブラリ |              | NVIDIA CUDA     | |
|  +---------------------------+              +-----------------+ |
+-----------------------------------------------------------------+
| OS・ハードウェア (Windows, NVIDIA GPU)                          |
+-----------------------------------------------------------------+

第4章 環境構築の前に知っておきたいWindowsの基礎

この章では、環境構築の手順を進める上で必要となるWindowsの基本的な操作や概念について解説する。ここで学ぶ知識は、続くインストール手順で頻繁に必要となるため、事前に理解しておくとスムーズに進められる。

AI開発における重要概念

• パッケージマネージャー: ソフトウェアの自動インストール・管理ツール（pip、wingetなど）
• 依存関係: あるソフトウェアが動作するために必要な他のソフトウェア
• 仮想環境: プロジェクトごとに独立したPython環境を作成する仕組み
• GPU/CPU: GPU（並列計算に特化）はAI計算を高速化、CPU（汎用計算）は制御処理を担当

4.1 フォルダ（ディレクトリ）、パス

フォルダとディレクトリは同じ概念を指す用語である。フォルダはWindows等のGUI環境で一般的に使われる呼称であり、ディレクトリはコマンドライン操作やプログラミングの文脈で使われる呼称である。本ガイドでは、文脈に応じて両方の用語を使用する。フォルダ（ディレクトリ）は、複数のファイルやフォルダを格納するための仕組みであり、大量のファイルを整理して管理できる。

パスは、コンピュータ上でファイルやフォルダの位置を示す文字列である。例えば、「C:\Users\金子さん\Documents\研究\データ.xlsx」は、Cドライブ（コンピュータ内の記憶装置）にUsersフォルダがあり、その中に金子さんフォルダがあり、さらにその中にDocumentsフォルダがあり、そこに「データ.xlsx」がある。このファイル「データ.xlsx」のパスは「C:\Users\金子さん\Documents\研究\データ.xlsx」になる。

4.2 環境変数とユーザープロファイル

環境変数

環境変数は、システム全体またはユーザーごとに共有される設定値を保存する仕組みである。環境変数には2種類ある。システム環境変数はすべてのユーザーに適用される設定であり、ユーザー環境変数は特定のユーザーにのみ適用される設定である。例えば、環境変数%USERPROFILE%には現在のユーザーのプロファイルディレクトリ名（例：C:\Users\金子さん）が格納されている。コマンドプロンプトなどで「%USERPROFILE%\Desktop」と記述することで、そのユーザーのデスクトップフォルダを参照できる。

ユーザープロファイル

ユーザープロファイルは、個人専用のフォルダ領域であり、Windowsの各ユーザーアカウント（コンピュータを使用する個人の登録情報）に対して個別に割り当てられる専用ディレクトリである。ユーザープロファイルにはユーザー固有のデータと設定が格納される。

• Windows 11ではユーザープロファイルは、C:\Users\ユーザー名になる（ユーザー「金子さん」の場合は C:\Users\金子さん）。
• コマンドプロンプト（コマンドでシステムを操作するツール）を起動すると、カレントディレクトリ（現在の作業対象となっているディレクトリ。作業ディレクトリとも呼ばれる）が、「C:\Users\金子さん>」のように表示される。コマンドプロンプトの起動直後は、カレントディレクトリがユーザープロファイルに設定される。コマンドプロンプトのカレントディレクトリは、cdコマンドで変更できる。

4.3 コマンドプロンプトの基本

コマンドプロンプトとは

コマンドプロンプトは、コマンドと呼ばれる文字列を入力してOSの機能を直接実行するための、文字ベースのユーザインターフェース（CUI）である。GUI（Graphical User Interface）と異なり、キーボード入力が中心になる。複雑な作業を効率的に行ったり、繰り返しの作業を自動化したりするのに役立つ。ソフトウェアのインストールや設定変更など、GUIでは対応が難しい操作もコマンドで行える。コマンドプロンプトには通常起動と管理者権限での起動の2つの方法がある。cdコマンドでカレントディレクトリを変更できる。また、ワイルドカード（*.tmp等）を使って複数のファイルを一括指定することも可能である。dir、copy、del等のコマンドでファイル操作を実行できる。

一般ユーザーと管理者

一般ユーザー権限であるか、管理者権限であるかによって、Windowsにおけるアクセス制御（誰が何を操作できるかを管理する仕組み）が行われる。アクセス制御は、重要なシステムファイルが誤って変更されることを防ぐのに役立つ。

• 一般ユーザー権限: 日常的な作業に必要な基本的な操作権限である。自分のユーザープロファイル内でのファイル操作、インストール済みアプリケーションの実行などが可能である。
• 管理者権限: システム全体を制御できる最高レベルの権限であり、システムの重要な設定やファイルを変更できる特別な権限である。一般ユーザー権限では C:\Windows\System32 などのシステムディレクトリへのファイル作成や、システム設定の変更ができないが、管理者権限では可能である。重要なシステム操作には管理者権限が必要となる。

コマンドプロンプトの起動

通常起動

起動方法はいくつかある。以下の手順で使用する「cmd」は、コマンドプロンプトを起動するためのプログラム名である。

• 方法① Windowsキーまたはスタートメニュー → cmdと入力 → コマンドプロンプトを選ぶ → Enter
• 方法② Windowsキー + R（同時押し） → cmdと入力 → Enter

管理者権限で起動

システム設定やソフトウェアのインストールなど、システムレベルの変更が必要な操作をコマンドプロンプトで実行するときは、管理者権限でコマンドプロンプトを起動する。

1. Windowsキーまたはスタートメニュー → cmdと入力
2. 「コマンドプロンプト」を右クリック → 「管理者として実行」を選択
3. 「このアプリがデバイスに変更を加えることを許可しますか」というメッセージが表示されたら「はい」をクリック

実行例

1. コマンドプロンプトを起動（通常起動）
2. 次のコマンドを実行する。echo を用いて環境変数 USERPROFILEの値を表示する。

   echo %USERPROFILE%

コマンド実行のパラメータ（オプション）

パラメータやオプション（コマンドの動作を細かく制御するための追加指示）により、コマンドに条件や設定を追加できる。例えば「dir /a」コマンドにおいて、dirは「ディレクトリ内容の表示」という指示であり、/aは「隠しファイルも含めて全て表示する」という追加指示である。

ワイルドカード

コマンド実行では、ワイルドカードと呼ばれる「何でも当てはまる」という意味を持つ特殊文字を用いて、複数のファイルを一度に指定できる。例えば、「*.tmp」は「拡張子が.tmpであるすべてのファイル」を意味し、テスト.tmp、12345.tmp などのファイル名とマッチする。別の例として、「data_*.xlsx」は「data_で始まるすべてのExcelファイル」を指定する。これは、ファイル名の一部について、任意の文字列にマッチするパターンマッチング（条件に合致するものを探す仕組み）を行うものである。

コマンドプロンプトによるファイル操作

コマンド入力後、Enterキーで実行が開始される。プロンプトには現在のカレントディレクトリ（現在操作対象となっているフォルダ）のパスが表示される。

基本的なファイル操作コマンド

• dir: ディレクトリ（フォルダ）の内容を表示するコマンドである。中のファイルやサブディレクトリ（サブフォルダ）などを一覧表示する。
  • dir: 現在のディレクトリ内容を詳細表示する
  • dir /a: 隠しファイルとシステムファイルを含む全ファイルを表示する
  • dir /s: サブディレクトリを含む階層的な内容を表示する
  • dir /w: ファイル名を横方向に整列表示する
• cd: カレントディレクトリを確認、移動するコマンドである
  • 使用例: cd Documents または cd ..（cd ..：親ディレクトリへ移動するための指定）
  • cd ディレクトリパス: カレントディレクトリを変更する。例：cd C:\Users
  • cd ..: カレントディレクトリを、親ディレクトリに移動する
  • cd（引数なし）：現在のカレントディレクトリを表示する
• mkdir: 新規ディレクトリ（フォルダ）を作成するコマンドである。使用例: mkdir project_folder または mkdir "My Project"
• rmdir: ディレクトリ（フォルダ）を削除するコマンドである
  • 使用例: rmdir /s /q old_project（/s：サブディレクトリも含めて削除するオプション、/q：確認メッセージを表示しないオプション）
  • rmdir ディレクトリ名: 空のフォルダーを削除する（/s オプションで中身ごと削除）
• del: 指定したファイルを削除するコマンドである
  • 使用例: del *.tmp （拡張子が「tmp」であるすべてのファイルを削除）
  • del ファイル名: ファイルを完全削除する（ごみ箱には移動されない）。/f オプションで読み取り専用ファイルも削除できる

ファイル内容の表示

• type ファイル名: テキストファイルの内容を表示する
• more ファイル名: 内容をページ単位で表示する
  • スペースキー：次ページへ移動
  • Enterキー：次行を表示
  • Qキー：表示を終了

ファイルとフォルダーの操作

• move 元名 新名: ファイルまたはフォルダーの名称変更や移動を行う
• copy 元名 先名: ファイルの複製を作成する
• xcopy /s /e /h 元フォルダー 先フォルダー: フォルダーを複製する
  • /s: 非空のサブディレクトリを含めて複製する
  • /e: 空のサブディレクトリを含めて複製する
  • /h: 隠しファイルとシステムファイルも複製する

実行例

1. 管理者権限でコマンドプロンプトを起動する。
2. 次のコマンドを実行する。notepad はテキストエディタ（メモ帳）を起動するコマンドである。

   dir
   cd ..
   mkdir test_folder
   cd test_folder
   notepad
   

4.4 エラーメッセージとの付き合い方

エラーメッセージは「失敗」ではなく、「問題解決へのヒント」である。エラーメッセージには、どのファイル（File）の何行目（line）で、どのような種類のエラー（例: ModuleNotFoundError）が起きたかなどが記載されている。エラーメッセージの一部や全体をコピーしてインターネットで検索したり、AIアシスタントで調査すると、解決策が見つかることが多い。

4.5 環境構築前のチェックリスト

• ディスク空き容量20GB以上を確認する
• 管理者権限でのコマンドプロンプト起動方法を確認する（4.3節参照）
• 既存のPython環境の有無を確認する
• NVIDIA GPUの有無を確認する（必要に応じて）
• インターネット接続を確認する

第5章 導入にあたっての推奨事項

スムーズな環境構築のため、以下の段階的な手順を推奨する。

1. 環境構築の基礎知識を学ぶ: 4章で説明したコマンドプロンプトの基本的な使い方など、Windowsでの環境構築に必要な基礎知識を確認する。
2. AI開発環境のインストール: Python本体、Git、7-Zip、開発エディタ、必要であればNVIDIA CUDAをPCにインストールする（6.1節参照）。
3. Pythonライブラリの導入: PyTorchなどのAI開発に必要なPythonライブラリをインストールする（6.2節参照）。
4. 開発エディタの活用: 3つの開発エディタ（Visual Studio Code, Jupyter Notebook, Windsurf）の特徴を理解し、状況に応じて活用する（7章参照）。

第6章 Windows でのAI開発環境インストール手順

注意

• 以下の手順では主にコマンドプロンプト（cmd.exe）を使用する（4.3節参照）。一部の操作では管理者権限での起動が必要である。
• wingetコマンドが利用できない場合は、Microsoft Storeから「アプリ インストーラー」をインストールする必要がある。
• 以下のコマンド例では、コメントを示すために REM を使用している。

6.1 AI開発環境のインストールと設定

用語の説明

インストールは、ソフトウェアをコンピュータで実行可能な状態にする処理である。プログラムファイルの配置、システムへの登録、設定などを行う。

winget（Windows Package Manager：Microsoft公式のソフトウェア管理ツール）は、ソフトウェアのインストールや管理を行うためのコマンドラインツール（文字コマンドで操作するプログラム）である。インストール作業を簡単なコマンドで実行できる。

インストールスコープは、ソフトウェアインストール時の対象ユーザーの範囲の指定である。wingetを用いたインストールでも重要な設定である。例えば、winget では、「--scope machine オプション（コマンドの動作を変更するための追加設定）」を指定してPythonをインストールすると、そのコンピュータのすべてのユーザーがPythonを使用できる。このオプションを指定しない場合、インストールを実行したユーザーのみがPythonを使用可能となる。

• --scope machine: すべてのユーザーが使用可能（インストール時に管理者権限必須）
• --scope user: 現在のユーザーのみが使用可能

AI開発環境の一括インストール

Pythonバージョンについて

本ガイド執筆時点（2025年12月）では、Python 3.14.2が最新安定版である。ただし、AI開発の入門としてはPython 3.12系列の利用を推奨する。これは多くのAIライブラリがPython 3.12で動作確認されており、安定性が確保されているためである。AnacondaやMinicondaなど、他の配布版もあるが、このガイドでは、wingetを用いてPython本体をインストールする。

コマンドの説明

• パス長制限の緩和: Windowsの既定では260文字のパス長制限があるが、AI開発では深いフォルダ階層を使うことがあるため、この制限を緩和する。
• CUDA 12.6: NVIDIA GPUを使用する場合に必要な計算基盤である。GPUがない場合はスキップ可能である。
• --scope machine: システム全体（全ユーザー）で使えるようにインストールする。
• --silent: インストール中の対話的な質問をスキップし、既定の設定で自動的にインストールする。
• -e: パッケージIDの完全一致検索（曖昧な検索を避ける）。

よくある間違いの回避策

• コマンドの途中で改行しない
• 管理者権限で実行していることを確認する（4.3節参照）
• インストール中にPCをスリープモードにしない
• Python がすでにインストール済みのときは、「winget install --scope machine --id Python.Python.3.12...」の実行のときに、「Modify Repair Uninstall」画面が表示されることがある。この画面が出た時は「Cancel」をクリックして次に進む。
• wingetコマンドが認識されない場合は、Windows 10の場合、Microsoft StoreからApp Installerをインストールする必要がある。

PATH設定コマンドの説明

• これらのコマンドは、各ツールの実行ファイルが置かれているフォルダをPATH環境変数に追加する。
• if existとif errorlevelを使って、既に設定されている場合は重複して追加しないようにしている。
• /Mオプションによりシステム環境変数として設定される。
• これらのコマンドを実行しても、特に結果は表示されない。エラーメッセージが出ない場合は実行に成功している。

インストール確認

新しいコマンドプロンプトを開き、以下のコマンドでバージョンが表示されれば成功である。

python --version
git --version

簡単なPythonの動作確認

コマンドプロンプトでpythonと入力すると、Pythonの対話モードが起動する。以下のコードを入力してエンターキーを押し、結果が表示されるか確認する。

print("Hello, AI World!")

>>>と表示されている行はPythonの入力受付中であることを示す。print("Hello, AI World!")と入力してエンターキーを押すと、その下の行にHello, AI World!と表示される。確認できたらexit()と入力してエンターキーを押すと対話モードを終了できる。エラーが出る場合は、9章のトラブルシューティングを参照すること。

6.2 Pythonライブラリの一括インストール

pipは、Pythonパッケージマネージャー（Pythonの追加機能を管理するためのツール）であり、ライブラリ（プログラムで使用できる機能の集合）のインストールや管理を行う。

• 使用例: pip install numpy
• このガイドでは pip installコマンドは、管理者権限で実行することを推奨する。Windowsのユーザー名が日本語の場合に発生する可能性があるトラブルを防止するためである。

pip基本コマンド

• pip install [パッケージ名]: 指定したパッケージ（機能をまとめたソフトウェア部品）をインストールする。
• pip install --upgrade [パッケージ名]（--upgrade：既存パッケージを最新版に更新するためのオプション）: 指定したパッケージを更新する。
• pip uninstall [パッケージ名]: 指定したパッケージを削除する。
• pip list: インストール済みパッケージを一覧表示する。
• pip show [パッケージ名]: 指定したパッケージの詳細情報を表示する。

主要なPythonライブラリの一括インストール

以下のコマンドで、AI開発に必要なライブラリを一括でインストールする。以下は本ガイド執筆時点（2025年12月）のコマンドである。管理者権限でコマンドプロンプトを起動し、次のコマンドを１つずつ実行する。

REM pipを最新版に更新
python -m pip install -U pip

REM PyTorchのインストール（CUDA 12.6対応版）
pip install -U torch torchvision torchaudio --index-url https://download.pytorch.org/whl/cu126

REM その他のAIライブラリを一括インストール
pip install jupyter ipykernel numpy pandas scikit-learn matplotlib japanize-matplotlib seaborn scipy opencv-python pillow timm pygame streamlit

重要： PyTorchのインストールコマンドは、PyTorch公式サイト（https://pytorch.org/get-started/locally/）で、自身の環境（Windows、Pip、Python、CUDA）に合った最新のコマンドを確認すること。特にGPUを利用する場合は、適切なCUDAバージョンの選択が重要である（6.3節参照）。

注意： 上記のコマンドはCUDA 12.6を使用する場合の例である。本ガイド執筆時点（2025年12月）では、PyTorch 2.6.0および2.7系でCUDA 12.6が正式サポートされている。

インストールされるPythonライブラリの説明

• PyTorch: ディープラーニング（深層学習）モデルを効率的に作るための主要なライブラリである。
• torchvision: 画像処理用のPyTorchライブラリである
• torchaudio: 音声処理用のPyTorchライブラリである
• jupyter: 開発エディタのJupyter Notebookである
• NumPy、Pandas、Scikit-learn: 数値計算（NumPy）、表形式データの操作・分析（Pandas）、古典的な機械学習（Scikit-learn）のためのライブラリである
• Matplotlib/Seaborn: データの分布や学習結果などをグラフで可視化するためのライブラリである
• japanize-matplotlib: Matplotlibで日本語を表示するためのライブラリである
• scipy: 科学計算ライブラリ（SciPy：高度な科学計算機能を提供）である
• opencv-python: 画像処理・コンピュータビジョン用ライブラリである
• pillow: 画像処理ライブラリ（Pillow：画像の読み込み、編集、保存機能を提供）である
• timm: PyTorch Image Models（事前学習済みモデル集）である
• pygame: ゲーム開発・インタラクティブアプリケーション用ライブラリである
• streamlit: Webベースの対話アプリ開発ツールである

インストール後の確認

コマンドプロンプトでpythonと入力し、対話モードに入って以下のコードを実行する。

# PyTorchのバージョン確認とGPU利用可能性の確認
import torch
print("PyTorch Version:", torch.__version__)
print("CUDA Available:", torch.cuda.is_available())
if torch.cuda.is_available():
    print("CUDA Version:", torch.version.cuda)

# 主要ライブラリのバージョン確認
import numpy as np
import pandas as pd
import matplotlib
print("NumPy Version:", np.__version__)
print("Pandas Version:", pd.__version__)
print("Matplotlib Version:", matplotlib.__version__)

エラーが出ずにバージョン情報が表示されれば成功である。特にCUDA Available: Trueと表示されていれば、PyTorchがGPUを認識しており、GPUを使った計算が可能である。Falseと表示された場合は、GPUが搭載されていないか、CUDAドライバやPyTorchのインストールに問題がある可能性がある（6.3節参照）。確認できたらexit()と入力して対話モードを終了する。動作確認でエラーが出た場合は、9章のトラブルシューティングを参照すること。

6.3 GPU利用時のPyTorchとCUDAのバージョン互換性

GPUを利用する場合、PyTorchとCUDAのバージョンの組み合わせが重要である。以下の手順で互換性を確認する。

1. 使用したいPyTorchのバージョンを決める: 最新安定版が推奨される。
2. PyTorch公式サイトのインストールページを確認する:
   • PyTorch公式サイト（https://pytorch.org/get-started/locally/）にアクセスする。
   • 「PyTorch Build」（Stable）、「Your OS」(Windows)、「Package」(Pipを選択)、「Language」(Python)、「Compute Platform」を選択する。
   • 「Compute Platform」で、利用したいCUDAのバージョン（例: CUDA 11.8、CUDA 12.6）を選択する。
   • 選択すると、下にインストールコマンドが表示される（例: pip install torch ... --index-url .../cu126）。このコマンドの末尾（cu126など）が、PyTorchが対応するCUDAバージョンを示す。
3. インストール済みCUDAバージョンを確認する: コマンドプロンプトで nvidia-smi を実行する。
4. インストール後にGPU認識を確認する: python -c "import torch; print(torch.cuda.is_available())" を実行する。

最新の互換性情報は https://docs.nvidia.com/cuda/cuda-toolkit-release-notes/ で確認すること。

第7章 開発エディタの活用

6.1節でインストールしたVisual Studio CodeとWindsurf、および6.2節でインストールしたJupyter Notebookについて、それぞれの特徴と適した用途を説明する。開発エディタにはそれぞれ特徴があり、併用も可能である。

開発エディタ選択フローチャート

開始
 |
 v
Windsurfを使用 -----------> 推奨：Windsurf
(AI支援・VS Code互換)       (第一候補)
 |
 v
Windsurfで不十分？ ---- No --> Windsurf継続使用
 |
 Yes
 |
 v
データ分析・グラフ重視？ - Yes --> Jupyter Notebook
 |                             または Google Colaboratory
 No                            (対話実行・可視化)
 |
 v
特殊なVS Code拡張必要？ - Yes --> Visual Studio Code
 |                             (限定的用途)
 No
 |
 v
Windsurfに戻る -----------> Windsurf
                           (標準選択)

① Visual Studio Code (VS Code)

Microsoftが開発するコードエディタである。「拡張機能」により、Python開発支援など様々な機能を追加してカスタマイズできる。

適した用途: プログラム開発、複数のファイルで構成されるプロジェクトの管理。

主なAI機能: GitHub CopilotやClaudeなどの拡張機能を導入することで、コード補完やチャットによる質問応答、コード生成といったAI支援機能を利用できる。

6.1節でインストールした拡張機能の説明

• ms-python.python: Python言語の基本サポート（シンタックスハイライト、デバッグ、リンティングなど）を提供する
• ms-python.vscode-pylance: Pythonの高度な言語サポート（型チェック、自動補完、定義へのジャンプなど）を提供する言語サーバーである
• MS-CEINTL.vscode-language-pack-ja: VS Codeの日本語化パックである
• dongli.python-preview: Pythonコードの実行結果をプレビュー表示する拡張機能である

② Jupyter Notebook

Webブラウザ上で動作する対話的な開発環境である。「セル」と呼ばれるブロック単位でコードを書き、実行するとその結果（数値、表、グラフなど）がすぐ下に表示される。インターフェースはシンプルで直感的である。より多くの機能が必要になったらJupyterLabへの移行も検討できる。

適した用途: データ分析、アルゴリズム、学習過程や結果の可視化、デモンストレーション。

主なAI機能

• コードの自動生成: 「# titanicデータセットを読み込み、最初の5行を表示」といったコメント（自然言語）をセルに書くと、AIが対応するPythonコードを自動で生成する。
• コードと結果の解説: 実行したコードや表示されたグラフが何をしているのか、自然言語で解説を生成させることができ、学習の助けになる。

③ Windsurf

AI統合開発環境（IDE）である。エディタ機能とAIとの連携が特徴である。

主なAI機能

• Cascade（エージェント型チャットボット）: 「# ファイルアップロード機能を持つWebアプリの雛形を作って」のような指示からコード生成やプロジェクト構築を行うなど、対話によるコード生成が可能である。
• Context Awareness（文脈認識）: 開いているプロジェクト全体のコードをAIが自動的に理解し、別のファイルに存在する関数や変数を考慮した上で、適切なコード補完や修正案を提示する。

第8章 このガイドのAI開発環境のメリットと注意点

8.1 メリット

• シンプルさ: インストールするツールの数を絞り、AI開発を始めやすい構成である。
• 標準的な構成: Python + pipの構成は広く利用されている。
• 開発エディタの選択肢: 開発スタイルに合わせて、VS Code、Jupyter Notebook、Windsurfといったエディタから選択できる。

8.2 注意点と潜在的な課題

• バージョン互換性: GPUを使う場合、NVIDIA CUDAとPyTorchの組み合わせには注意が必要である（6.3節参照）。
• コマンド操作への慣れ: ライブラリのインストールなど、基本的なコマンドプロンプトの操作に慣れる必要がある（4章参照）。
• 複数プロジェクトの管理: このシンプルな構成では、すべてのライブラリがPC全体で共有される。複数のプロジェクトで異なるバージョンのライブラリを使いたい場合は、環境管理（例：Pythonのvenv機能やconda）が必要になることに留意する必要がある。

第9章 一般的なトラブルシューティング

問題: pythonやpipコマンドが認識されない

エラーメッセージ例: 'python' is not recognized as an internal or external command, operable program or batch file.

原因: wingetでのインストールに失敗したか、パス（PATH）が正しく設定されていない可能性がある。

対処法: PCを再起動する。それでも解決しない場合は、Windowsの「設定」→「システム」→「バージョン情報」→「システムの詳細設定」→「環境変数」を開き、システム環境変数のPathにPythonのインストールフォルダ（例: C:\Program Files\Python312）が含まれているか確認すること。

問題: ライブラリが見つからない

エラーメッセージ例: ModuleNotFoundError: No module named 'xxx'

原因: 必要なライブラリ（例: torch、numpy、pandasなど）が正しくインストールされていないか、コマンドを実行しているPython環境とは異なる環境にインストールされている可能性がある。

対処法: pip install <ライブラリ名>コマンドを再実行する。また、pip listコマンドでインストール済みのライブラリ一覧を確認できる。

問題: GPUが認識されない、またはGPU関連のエラーが出る

エラーメッセージ例: CUDA is not availableなど

原因: インストールされているCUDAと、PyTorchが要求するCUDAバージョンの間に互換性がないことが主な原因である。その他、CUDAのインストール失敗、GPUハードウェアの問題なども考えられる。

対処法

1. 6.3節の手順を参考に、CUDAとPyTorchのバージョン互換性を再確認する。必要であれば、CUDAまたはPyTorchを再インストールする。
2. コマンドプロンプトでnvidia-smiを実行し、NVIDIAドライバが正しくインストールされ、GPUがシステムに認識されているか確認する。
3. Pythonで以下のコードを実行してPyTorchがGPUを認識しているか確認する。

   import torch
   print(torch.cuda.is_available())
   print(torch.version.cuda)
   

   Trueが返ってくればPyTorchはGPUを認識している。Falseの場合は、pip uninstall torchで一度アンインストールし、PyTorch公式サイトで確認した正しいコマンドでPyTorchを再インストールすることを検討すること。

4. PCの再起動も試す。
5. 次の手順で、NVIDIAドライバの更新も試みる。
   • NVIDIA公式サイトのドライバダウンロードページにアクセスする
   • GPUモデル、OS、ドライバタイプを選択する
   • 最新版をダウンロードし、インストーラーを実行する（「クリーンインストール」推奨）
   • 確認（コマンドプロンプト）: nvidia-smi

第10章 このガイドを終えたら：次のステップへ

これで、Windows PC上にAI開発の基本的な環境が構築できた。

この後、AI開発やプログラミング学習をさらに進めるためのステップをいくつか案内する。

• Pythonの基本を学ぶ: まだPythonに慣れていない場合は、変数、オブジェクト、メソッド、クラス、インポート、関数、データ型、制御構文（if文、for文）といった基本的な文法や概念を学ぶのが最初のステップである。
• Pythonの基本的なライブラリを使う: インストールしたNumPyやPandasなどを使って、データの読み込み、表示、集計などの操作を試す。実際のデータを扱う経験はAI開発の基礎となる。
• 開発環境を使いこなす: WindsurfのAI機能やデバッグ機能を使ったり、Jupyter Notebookでデータ分析を進めたりなど、開発環境の便利な機能を積極的に使う。
• 仮想環境について学ぶ: 複数のプロジェクトで異なるライブラリのバージョンを使いたいなど、より進んだ環境管理が必要になったら、Pythonの仮想環境（venvやcondaなど）について学ぶことを推奨する。

このガイドで構築した環境を使い、様々なコードを試すことができる。AI開発の学習が充実したものとなることを期待する。