Windows ローカル AI エディタ活用ガイド（Windsurf・VS Code・JupyterLab）

重要概念

• AI エディタ: AI 機能を統合したコードエディタおよび IDE（統合開発環境）の総称。コード補完、コード生成、エラー修正提案、対話による開発支援等の機能を持つ。本ガイドでは、AI が自律的にファイル編集を行うエージェント型の Windsurf、Cline 拡張を導入した Visual Studio Code、対話的開発環境の JupyterLab の 3 種類を扱う。
• Cline: Visual Studio Code の拡張機能。AI によるファイル操作、ターミナル実行、複数ファイルの編集ができるエージェント型ツールである。接続先の AI モデルを設定でき、本ガイドでは Ollama によるローカル AI に接続する。
• Ollama: ローカル AI モデルの実行基盤。PC 上でモデルを動かし、ローカル API（http://localhost:11434）として提供する。アカウント登録や API キーが不要であり、コードやデータが外部に送信されない。
• ビルドツール: ソースコードを実行可能な形式に変換するツール群（VS Build Tools 等）。Python 開発では、C/C++ で書かれた拡張ライブラリのコンパイル等に使用する。
• GPU 計算基盤 (CUDA): NVIDIA GPU 用の並列計算基盤。GPU を GPGPU（汎用 GPU 計算：グラフィックス処理以外の計算に GPU を利用する技術）として活用し、行列演算等を高速に処理する。
• 環境変数 PATH: Windows がプログラムを探索するディレクトリのリスト。ここに Python や Git 等のディレクトリを追加することで、コマンドプロンプトから直接コマンドを実行できる。

目標と全体像

目標

本ガイドの目標は、自身のパソコンで AI エディタを使った AI プログラミングの実行と実験が可能な環境を構築し、AI エディタを使いこなすことである。本ガイドを完了すると、AI プログラムを動作させ、AI 支援を受けながらソースコードを確認・修正できる環境が整う。

Python の役割

Python は AI プログラミングで広く利用されているプログラミング言語である。機械学習やディープラーニングのライブラリが豊富であり、初学者にも扱いやすいという特徴がある。

AI プログラミングにおける開発環境の全体像

本ガイドでは以下のソフトウェアをインストールする。

開発環境とビルドツール

実行前の確認事項

• ディスク空き容量が 40GB 以上あることを確認する（内訳の目安は冒頭の【本ガイドの前提と方針】を参照）。
• NVIDIA GPU 搭載 PC の場合：コマンドプロンプトで nvidia-smi を実行し、NVIDIA ドライバが導入済みであることを確認する。コマンドが認識されない場合は、NVIDIA 公式サイトから最新ドライバを導入してから本ガイドを進める。
• GPU 非搭載 PC の場合：CUDA Toolkit のインストール節をスキップし、PyTorch は CPU 版を導入する（後述）。

AI エディタの機能と注意事項

AI エディタは次の機能を備えており、Python やその他のプログラミング言語の開発に使用されている。

AI エディタの機能：

• コード生成支援：自然言語での指示から Python コードを生成
• エラー検出支援：構文エラーの検出と修正提案
• コード改善提案：既存コードの改善案の提示
• 学習支援：プログラミング概念の説明とコーディング例の提示
• デバッグ支援：エラーの可能性のある箇所の指摘と対処法の提案

注意事項：

AI エディタは開発を支援するツールであり、コード生成や修正提案が正確でない場合がある。生成されたコードや提案内容は理解し検証してから使用し、最終的な判断は開発者自身が行うものである。授業課題や研究での利用可否については、担当教員・指導教員の指示に従うこと。

ここで紹介する 3 つの AI エディタ

本ガイドでは、以下の 3 つの AI エディタを扱う。いずれも基本機能を無料で利用でき、Python 開発に適している。Cline は Ollama によるローカル AI に接続するため、登録不要・無料で、コードを外部に送信せずに利用できる。なお、他に JetBrains 製品や Vim 系エディタ等の選択肢も存在する。

1. Windsurf

AI 統合 IDE（統合開発環境：プログラムの編集、実行、デバッグを一つのソフトウェアで行える環境）。開発者の指示に基づき AI がコードを編集する機能（Cascade）を搭載する。AI が自律的に複数ファイルを編集するエージェント型の利用に向く。

2. Visual Studio Code + Cline

マイクロソフト製エディタに、Cline 拡張機能で AI 支援機能を追加した構成。Cline はエージェント型で、AI がファイル操作・ターミナル実行・複数ファイルの編集を行う。本ガイドでは Cline を Ollama によるローカル AI に接続し、登録不要・無料で安全に利用する。

3. JupyterLab

Web ブラウザ上で動作する対話的開発環境。「セル」と呼ばれるブロック単位でコードを書き、実行するとその結果（数値、表、グラフ等）がすぐ下に表示される。データ分析、アルゴリズムの検証、学習過程や結果の可視化に向く。

Python 3.12 のインストール

本章では、Python のインストール を行い、Python のプログラムを実行する環境を整える。扱う環境は、Windows 搭載パソコンである。金子研究室では、Python 3.12.10 を推奨する。

REM Python 3.12 をシステム領域にインストール
winget install --id Python.Python.3.12 -e --scope machine --silent --accept-source-agreements --accept-package-agreements --override "/quiet InstallAllUsers=1 PrependPath=1 Include_test=0 Include_pip=1 Include_launcher=1 InstallLauncherAllUsers=1 TargetDir=\"C:\Program Files\Python312\""

REM Python と Scripts を PATH 先頭に追加
powershell -NoProfile -Command "$p='C:\Program Files\Python312'; $s=\"$p\Scripts\"; $c=[Environment]::GetEnvironmentVariable('Path','Machine'); if((Test-Path $p) -and (';'+$c+';' -notlike \"*;$p;*\") -and (';'+$c+';' -notlike \"*;$s;*\")){[Environment]::SetEnvironmentVariable('Path',\"$p;$s;$c\",'Machine')}"

python --version

Build Tools・CUDA Toolkit・PyTorch のインストール

本章では、C++ ビルドツール、NVIDIA CUDA Toolkit、PyTorch のインストールを行い、GPU を活用した機械学習プログラムを実行する環境を整える。扱う環境は、Windows 搭載パソコンである。

REM VC++ ランタイム
winget install --scope machine --id Microsoft.VCRedist.2015+.x64 -e --silent --disable-interactivity --force --accept-source-agreements --accept-package-agreements --override "/quiet /norestart"

REM ============================================================
REM Visual Studio Build Tools + Desktop development with C++
REM （VCTools、MSBuildTools、CMake連携、Clang、Windows 11 SDK）
REM ============================================================
REM 進行中のインストーラーを停止（ロック競合回避）
taskkill /F /IM vs_setup.exe /T >nul 2>&1
taskkill /F /IM vs_installer.exe /T >nul 2>&1
taskkill /F /IM vs_installerservice.exe /T >nul 2>&1

REM 未インストール時: winget で新規インストール
REM インストール済み時: setup.exe modify でコンポーネント追加（バージョンは変更しない）
winget list --id Microsoft.VisualStudio.BuildTools 2>nul | findstr /i "BuildTools" >nul 2>&1
if %ERRORLEVEL% EQU 0 (
    for /f "usebackq delims=" %P in (`"C:\Program Files (x86)\Microsoft Visual Studio\Installer\vswhere.exe" -products Microsoft.VisualStudio.Product.BuildTools -property installationPath`) do start /wait "" "C:\Program Files (x86)\Microsoft Visual Studio\Installer\setup.exe" modify --installPath "%P" --add Microsoft.VisualStudio.Workload.VCTools --add Microsoft.VisualStudio.Workload.MSBuildTools --add Microsoft.VisualStudio.Component.VC.CMake.Project --add Microsoft.VisualStudio.Component.VC.Llvm.Clang --add Microsoft.VisualStudio.Component.VC.Llvm.ClangToolset --add Microsoft.VisualStudio.Component.Windows11SDK.26100 --includeRecommended --quiet --norestart --nocache
) else (
    winget install --scope machine --id Microsoft.VisualStudio.BuildTools -e --silent --disable-interactivity --force --accept-source-agreements --accept-package-agreements --override "--quiet --wait --norestart --nocache --add Microsoft.VisualStudio.Workload.VCTools --includeRecommended --add Microsoft.VisualStudio.Workload.MSBuildTools --add Microsoft.VisualStudio.Component.VC.CMake.Project --add Microsoft.VisualStudio.Component.VC.Llvm.Clang --add Microsoft.VisualStudio.Component.VC.Llvm.ClangToolset --add Microsoft.VisualStudio.Component.Windows11SDK.26100"
)

REM 破損時の修復（任意、動作がおかしくなった場合）
REM "C:\Program Files (x86)\Microsoft Visual Studio\Installer\setup.exe" repair --installPath "C:\Program Files (x86)\Microsoft Visual Studio\18\BuildTools" --quiet --norestart

REM 導入確認（インストールパスが表示されれば正常）
"C:\Program Files (x86)\Microsoft Visual Studio\Installer\vswhere.exe" -products * -requires Microsoft.VisualStudio.Workload.VCTools -property installationPath

REM NVIDIA CUDA Toolkit 12.8 をシステム領域にインストール
winget install --scope machine --id Nvidia.CUDA --version 12.8 -e --silent --disable-interactivity --force --uninstall-previous --accept-source-agreements --accept-package-agreements --override "-s -n"

REM 環境変数TEMP, TMPの設定（一時ファイルの保存先を短いパスに変更）
mkdir C:\TEMP
setx TEMP "C:\TEMP" /M
setx TMP "C:\TEMP" /M

nvcc --version

pip install --no-user -U numpy torch torchvision torchaudio --index-url https://download.pytorch.org/whl/cu128

Ollama・モデル・Open WebUI のインストール

Ollama、3 つのモデル（LFM2.5-1.2B-Instruct、gemma4:e2b-it-qat、gemma4:12b-it-qat）、埋め込みモデル bge-m3、および Open WebUI を導入する。あわせて、本手順で使う設定（コンテキスト長 262144、KV キャッシュ q8_0、Flash Attention）を一度だけ設定する。Flash Attention は KV キャッシュの量子化に必要な高速化機能である。

ハードウェアの前提

• ディスク空き容量 20GB 以上、メモリ搭載量 16GB 以上を推奨（モデル 3 種で合計約 12GB ＋ Open WebUI 等）。少 VRAM の GPU や CPU のみの PC でも動作するが、gemma4:12b-it-qat は時間がかかる場合がある。
• 推論時のメモリ占有は 1 モデル分（モデル切替時に Ollama が自動でアンロードおよびロードを行う）。

ハードウェア要件の事前確定は難しい。新規に PC を準備する前に、現有の機器で本手順を試行し、性能面の問題の有無を確認したうえで、本格運用のハードウェアを決定する。

【インストールコマンドの実行方法】

管理者権限でコマンドプロンプトを起動する（手順：Windows キーまたはスタートメニュー → cmd と入力 → 右クリック → 「管理者として実行」）。winget の --scope machine オプションでシステム全体にインストールするには、管理者権限が必要である。実行時はコマンド全体をコマンドプロンプトにコピー＆ペーストする。

REM ============================================================
REM 管理者権限チェック
net session >nul 2>&1
if errorlevel 1 ( echo [エラー] 管理者権限で実行してください & pause & exit /b 1 )

REM winget パッケージ一覧のローカルキャッシュを更新
winget source update

REM === 1. Ollama 環境変数を Machine スコープで事前設定 ===
REM   インストール前に設定することで、Ollama 起動時から正しい設定が読み込まれる
powershell -NoProfile -Command "[System.Environment]::SetEnvironmentVariable('OLLAMA_FLASH_ATTENTION', '1', 'Machine')"
powershell -NoProfile -Command "[System.Environment]::SetEnvironmentVariable('OLLAMA_KV_CACHE_TYPE', 'q8_0', 'Machine')"
REM   コンテキスト長：Ollama のデフォルトは 4096。
REM   ここでは gemma4:12b-it-qat の上限 262144 に設定する
powershell -NoProfile -Command "[System.Environment]::SetEnvironmentVariable('OLLAMA_CONTEXT_LENGTH', '262144', 'Machine')"
powershell -NoProfile -Command "[System.Environment]::SetEnvironmentVariable('OLLAMA_MODELS', 'C:\Ollama\models', 'Machine')"
set "OLLAMA_FLASH_ATTENTION=1"
set "OLLAMA_KV_CACHE_TYPE=q8_0"
set "OLLAMA_CONTEXT_LENGTH=262144"
set "OLLAMA_MODELS=C:\Ollama\models"

REM === 2. 既存の Ollama プロセスを停止（ファイルロック解除のため） ===
taskkill /IM ollama.exe /F >nul 2>&1
taskkill /IM "ollama app.exe" /F >nul 2>&1

REM === 3. モデルフォルダの作成と権限設定 ===
if not exist "C:\Ollama\models" mkdir "C:\Ollama\models"
icacls "C:\Ollama\models" /grant *S-1-5-32-545:(OI)(CI)(M) /T /C

REM === 4. 既存モデルの移動（ユーザープロファイルに残っている場合） ===
REM   Ollama 停止状態で実行するためファイルロックが起きない
if exist "%USERPROFILE%\.ollama\models" robocopy "%USERPROFILE%\.ollama\models" "C:\Ollama\models" /E /MOVE
if exist "%USERPROFILE%\.ollama\models" rd /s /q "%USERPROFILE%\.ollama\models"

REM === 5. winget パッケージ一覧のローカルキャッシュを更新 ===
winget source update

REM === 6. Ollama のインストール（Inno Setup） ===
winget uninstall --id Ollama.Ollama -e --silent --disable-interactivity --accept-source-agreements
REM   uninstall 後にプロセスが残ることがあるため再度停止
taskkill /IM ollama.exe /F >nul 2>&1
taskkill /IM "ollama app.exe" /F >nul 2>&1
winget install --id Ollama.Ollama -e --silent --disable-interactivity --force --accept-source-agreements --accept-package-agreements --custom "/DIR=C:\Ollama"
winget upgrade --id Ollama.Ollama -e --silent --disable-interactivity --force --accept-source-agreements --accept-package-agreements --custom "/DIR=C:\Ollama"

REM === 7. Ollama のパス設定（システム PATH に未登録の場合のみ追加） ===
powershell -NoProfile -Command "$p='C:\Ollama'; $c=[Environment]::GetEnvironmentVariable('Path','Machine'); if((Test-Path $p) -and (';'+$c+';' -notlike \"*;$p;*\")){[Environment]::SetEnvironmentVariable('Path',\"$c;$p\",'Machine')}"

REM   Ollama のパスを現在のセッションに反映
set "PATH=C:\Ollama;%PATH%"

REM === 8. Ollama サービスの起動（モデルダウンロードの前に必要） ===
where ollama >nul 2>&1
if errorlevel 1 echo Ollama のパスが見つかりません。再起動後に再実行してください。 & exit /b 1
tasklist /fi "imagename eq ollama.exe" | find "ollama.exe"  2>&1
if errorlevel 1 start "" "C:\Ollama\ollama.exe" serve & timeout /t 10 /nobreak

REM === 9. モデルのダウンロード ===
REM   動作確認用（テキスト専用、約 731MB）。
echo LFM2.5-1.2B-Instruct モデルをダウンロード中...
ollama pull LiquidAI/lfm2.5-1.2b-instruct
REM   画像入力対応（軽量、約 4.3GB）
echo gemma4:e2b-it-qat モデルをダウンロード中...
ollama pull gemma4:e2b-it-qat
REM   画像入力対応（上位、約 7.2GB）
echo gemma4:12b-it-qat モデルをダウンロード中...
ollama pull gemma4:12b-it-qat
echo モデルダウンロード完了

REM === 10. 埋め込みモデルのダウンロード（RAG 演習で使用） ===
echo bge-m3 埋め込みモデルをダウンロード中...
ollama pull bge-m3
echo 埋め込みモデルダウンロード完了

REM === 11. Open WebUI のインストール ===
REM   open-webui パッケージにより、依存パッケージ（FastAPI、ChromaDB、
REM   sentence-transformers 等）が一括インストールされる
python -m pip install --no-user --upgrade pip
python -m pip install --no-user --upgrade open-webui
python -m pip uninstall -y open-webui
python -m pip install --user --upgrade open-webui

REM === 12. Git のインストール ===
winget install --scope machine --id Git.Git -e --silent --disable-interactivity --force --accept-source-agreements --accept-package-agreements --override "/VERYSILENT /NORESTART /NOCANCEL /SP- /CLOSEAPPLICATIONS /RESTARTAPPLICATIONS /COMPONENTS=""icons,ext\reg\shellhere,assoc,assoc_sh"" /o:PathOption=Cmd /o:CRLFOption=CRLFCommitAsIs /o:BashTerminalOption=MinTTY /o:DefaultBranchOption=main /o:EditorOption=VIM /o:SSHOption=OpenSSH /o:UseCredentialManager=Enabled /o:PerformanceTweaksFSCache=Enabled /o:EnableSymlinks=Disabled /o:EnableFSMonitor=Disabled"

REM   Git のパスを現在のセッションに反映
set "PATH=C:\Program Files\Git\cmd;%PATH%"

REM === 13. スタートメニュー ショートカット作成 ===
REM   gemma4:e2b-it-qat 起動ショートカット（CUI で質問・応答を行う）
powershell -NoProfile -Command "$s=New-Object -ComObject WScript.Shell; $l=$s.CreateShortcut([Environment]::GetFolderPath('CommonPrograms')+'\Ollama Gemma4 e2b.lnk'); $l.TargetPath='cmd.exe'; $l.Arguments='/k \"start cmd /k ollama serve ^& timeout /t 3 /nobreak ^>nul ^& ollama run gemma4:e2b-it-qat\"'; $l.Save()"

echo インストール完了

インストール後の動作確認

重要：動作確認は、新しくコマンドプロンプトを開いて実行する。インストール前に開いていたコマンドプロンプトでは、環境変数の変更が反映されない。

Python 3.12 の動作確認

新しくコマンドプロンプトを起動し、以下のコマンドを実行して Python のバージョンを確認する。

python --version

「Python 3.12.x」と表示されれば正常にインストールが完了している。

Git の動作確認

以下のコマンドを実行して Git のバージョンを確認する。

git --version

「git version x.x.x」と表示されれば正常にインストールが完了している。

CUDA 12.8 の動作確認

GPU 搭載 PC のみ実施する。以下のコマンドを実行して CUDA のバージョンを確認する。

nvcc --version

「Cuda compilation tools, release 12.8」と表示されれば正常にインストールが完了している。

PyTorch の動作確認

以下のコマンドを実行して PyTorch バージョン、CUDA の動作、GPU 数を確認する。

python -c "import torch; print(torch.__version__)"
python -c "import torch; print(torch.cuda.is_available())"
python -c "import torch; print(torch.cuda.device_count())"

NVIDIA 製 GPU を搭載している場合、torch.cuda.is_available() は True を返し、torch.cuda.device_count() は GPU の数（1 以上）を返す。GPU を搭載していないパソコンでは、torch.cuda.is_available() は False、torch.cuda.device_count() は 0 を返す。

Ollama の動作確認

以下のコマンドを実行して Ollama のバージョンと、ダウンロード済みモデルの一覧を確認する。

ollama --version
ollama list

バージョン番号が表示され、ollama list に gemma4:e2b-it-qat や LiquidAI/lfm2.5-1.2b-instruct 等のモデルが表示されれば正常である。次のコマンドで、ローカル AI に実際に質問して応答を確認できる。

ollama run gemma4:e2b-it-qat "こんにちは。あなたは何ができますか。"

コマンドが認識されない場合の確認手順

上記いずれかのコマンドが「内部コマンドまたは外部コマンドとして認識されていません」と表示される場合、以下の順に確認する。

1. 新しいコマンドプロンプトを開き直す：環境変数の変更は、変更後に新規に起動したプロセスにのみ反映される。
2. PATH の内容を確認する：echo %PATH% を実行し、対象ソフトウェア（Python、Git、CUDA、Ollama 等）のディレクトリが含まれているかを確認する。
3. 実体の所在を確認する：where python、where git、where ollama 等で実行ファイルが見つかるかを確認する。見つからない場合は当該ソフトウェアのインストール自体が失敗している可能性がある。
4. システム環境変数とユーザ環境変数を確認する：「設定」→「システム」→「バージョン情報」→「システムの詳細設定」→「環境変数」で、システム環境変数の PATH に対象ディレクトリが含まれていることを確認する。

AI エディタのインストール

Python プログラムの編集・実行には、AI エディタを使用できる。本節では、第 3 節で紹介した 3 つの AI エディタ（Windsurf、Visual Studio Code + Cline、JupyterLab）をインストールする。

JupyterLab のインストール（Windows 上）

管理者権限のコマンドプロンプトで以下を実行して、JupyterLab をインストールする。

REM JupyterLab をインストール
set "PYTHON_PATH=C:\Program Files\Python312"
"%PYTHON_PATH%\Scripts\pip" install -U jupyterlab

AI エディタ Windsurf のインストール（Windows 上）

Windsurf をインストールする。Windsurf がインストール済みの場合、この手順は不要である。

管理者権限のコマンドプロンプトで以下を実行する。

winget install --scope machine --id Codeium.Windsurf -e --silent --disable-interactivity --force --accept-source-agreements --accept-package-agreements --custom "/SP- /SUPPRESSMSGBOXES /NORESTART /CLOSEAPPLICATIONS /DIR=""C:\Program Files\Windsurf"" /MERGETASKS=!runcode,addtopath,associatewithfiles,!desktopicon"
powershell -Command "$env:Path=[System.Environment]::GetEnvironmentVariable('Path','Machine')+';'+[System.Environment]::GetEnvironmentVariable('Path','User'); windsurf --install-extension MS-CEINTL.vscode-language-pack-ja --force; windsurf --install-extension ms-python.python --force; windsurf --install-extension Codeium.windsurfPyright --force"

--scope machine を指定することで、システム全体（全ユーザ向け）にインストールされる。インストール完了後、コマンドプロンプトを再起動すると PATH が反映される。

Visual Studio Code と Cline のインストール（Windows 上）

管理者権限のコマンドプロンプトで以下を実行して、Visual Studio Code をシステム全体にインストールし、関連する拡張機能（Cline を含む）を導入する。

REM Microsoft VS Code をシステム領域にインストール
winget install --scope machine --id Microsoft.VisualStudioCode -e --silent --accept-source-agreements --accept-package-agreements

REM VS Code 拡張機能のインストール（Python 環境、日本語化、Cline）
if exist "C:\Program Files\Microsoft VS Code\bin" cd "C:\Program Files\Microsoft VS Code\bin"
if exist "C:\Program Files\Microsoft VS Code\bin" code --install-extension ms-python.python
if exist "C:\Program Files\Microsoft VS Code\bin" code --install-extension ms-python.vscode-pylance
if exist "C:\Program Files\Microsoft VS Code\bin" code --install-extension MS-CEINTL.vscode-language-pack-ja
if exist "C:\Program Files\Microsoft VS Code\bin" code --install-extension dongli.python-preview
if exist "C:\Program Files\Microsoft VS Code\bin" code --install-extension saoudrizwan.claude-dev

上記のコマンドでは、Visual Studio Code のインストールに加えて、以下の拡張機能を自動的にインストールしている。

• ms-python.python：Python 言語サポート（構文ハイライト、デバッグ機能等）
• ms-python.vscode-pylance：Python 用の言語サーバ（コード補完、型チェック等）
• MS-CEINTL.vscode-language-pack-ja：日本語言語パック
• dongli.python-preview：Python コードの実行結果プレビュー
• saoudrizwan.claude-dev（Cline）：AI によるファイル操作、ターミナル実行、複数ファイルの編集ができる拡張機能

導入後の設定と使い始め

7.1 Windsurf の設定と基本操作

Windsurf は、AI 補完機能（Tab）と AI チャット機能（Cascade）を統合したエディタである。AI が複数ファイルを自律的に編集するエージェント的な利用に向く。

初期設定

1. スタートメニューから Windsurf を起動する
2. アカウント登録は任意である。登録なしでも AI 補完機能は利用できる
3. Python 実行環境の確認：Terminal（ターミナル：コマンド入力画面）を開き、python --version を実行する

4. Python 実行環境の設定確認：Ctrl+Shift+P を押し、「Python: Select Interpreter」を選択する。システムにインストールされた Python 3.12 が選択されていることを確認する（選択されていなければ変更する）

Windsurf の AI コード補完機能（Autocomplete）の使い方

Windsurf の AI コード補完は、AI モデルがカーソル位置の文脈、変数の型、プロジェクト全体の構造を解析し、次に記述すべきコードを推論・提示する機能である。

基本動作：
入力を開始すると、AI が推論したコードが灰色の文字（ゴーストテキスト）としてエディタ上に表示される。

キー操作一覧（ショートカット、VS Code 版）：

実践例：
Python におけるリスト操作関数の実装例である。コメントを記述することで、AI に意図を伝え、精度の高い補完を得られる。

# 数値リストを受け取り、その平均値を計算する関数
# 例外処理：リストが空の場合は0を返す
def calculate_average(numbers):
    if not numbers:
        return 0
    return sum(numbers) / len(numbers)

上の 2 行のコメントを入れ、「def」まで入力すると、残りを AI が補完する。

Cascade（AI チャット機能）の使い方

Cascade は、AI と対話しながら複数ファイルの作成・編集、コードの説明、エラー修正等を行う機能である。無料プランでは利用回数に制限がある。

起動方法：

• Windows/Linux：Ctrl+L

モード：

• Code モード：複数ファイルの作成・編集が可能。AI が実際にファイルを変更する
• Ask モード：コードの説明や質問応答。ファイルは変更しない

実践例：

1. Ctrl+L（または Cmd+L）で Cascade を起動する
2. Code モードを選択する

3. 例えば、「バグをすべて解決して」と入力する

バグの発見と解決、コメントの追加、説明文の作成、機能の追加や変更、コード内の冗長部分の削除等を依頼できる。

4. AI がファイルを解析し、変更案を提示する
5. 変更内容を確認して承認する（承認する場合には、「Accept」をクリック）

7.2 Visual Studio Code + Cline の設定と使い方

Cline は、AI がファイル操作・ターミナル実行・複数ファイルの編集を自律的に行うエージェント型の拡張機能である。本ガイドでは Cline を Ollama によるローカル AI に接続する。これにより、アカウント登録や API キーが不要で、コードを外部に送信せずに安全に利用できる。

初期設定

1. スタートメニューから VS Code を起動する
2. Cline 拡張機能がインストールされていることを確認する（左サイドバーに Cline のアイコンが表示される）
3. Ollama が起動していることを確認する。「Ollama・モデル・Open WebUI のインストール」の手順で Ollama サービスは起動済みだが、起動していない場合は、コマンドプロンプトで ollama serve を実行する

Cline を Ollama（ローカル AI）に接続する

登録不要・安全なローカル AI に接続するため、以下の手順で設定する。

1. 左サイドバーの Cline アイコンをクリックして、Cline パネルを開く
2. Cline パネル右上の設定（歯車）アイコンをクリックする
3. API Provider のドロップダウンから Ollama を選択する
4. Base URL に http://localhost:11434 を入力する（Ollama のローカル API のアドレスである）
5. Model に、ダウンロード済みのモデル名（例：gemma4:e2b-it-qat）を入力する
6. 設定を保存する

以上で、Cline がローカル AI に接続される。Ollama はアカウント登録や API キーが不要であり、コードやデータが外部に送信されない。Ollama が起動していない場合は、コマンドプロンプトで ollama serve を実行する。

Cline の使い方

Cline は、開発者の指示に基づき AI が自律的にファイルを編集する。

1. Cline パネルの入力欄に、行いたいことを自然言語で入力する（例：「バグをすべて解決して」）
2. AI がファイルを解析し、変更案（編集内容やコマンド）を提示する
3. 変更内容を確認して承認する。Cline は各ステップで承認を求めるため、内容を理解したうえで承認する

バグの発見と解決、コメントの追加、説明文の作成、機能の追加や変更、コード内の冗長部分の削除等を依頼できる。ローカル AI のモデルは、クラウドの大規模モデルに比べて性能が限られる場合がある。複雑なタスクでは、gemma4:12b-it-qat のような上位モデルに切り替えると精度が向上することがある（Model 欄のモデル名を変更する）。

7.3 JupyterLab の設定と使い方

JupyterLab は、セル単位でコードを書いて実行し、結果をその場で確認できる対話的開発環境である。データ分析や可視化に向く。

起動方法

コマンドプロンプトで以下を実行する。Web ブラウザが開き、JupyterLab の画面が表示される。

jupyter lab

基本操作

• 新しいノートブックを作成し、セルに Python コードを入力する
• Shift+Enter でセルを実行する。実行結果（数値、表、グラフ等）がセルのすぐ下に表示される
• コメント（自然言語）をセルに書くことで、AI 補完に意図を伝えられる

これらの AI エディタと拡張機能により、Python 開発の環境が構築される。各ツールの特性を理解し、用途に応じて使い分けることを推奨する。

次のステップ

パッケージ管理ツール pip の活用

pip（Python に標準搭載されているパッケージ管理ツール）を使用すると、他の開発者が作成したライブラリを追加できる。例えば、データ分析、画像処理、Web アプリケーション開発等、各分野の機能を利用できる。